**************************************************************************
      * DBG110DF: Menu for DBG utilities
      * Copyright (C) 2000  Martin Rowe  <martin@dbg400.net>
      *
      * This program is free software; you can redistribute it and/or modify
      * it under the terms of the GNU General Public License as published by
      * the Free Software Foundation; either version 2 of the License, or
      * (at your option) any later version.
      *
      * This program is distributed in the hope that it will be useful,
      * but WITHOUT ANY WARRANTY; without even the implied warranty of
      * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
      * GNU General Public License for more details.
      *
      * You should have received a copy of the GNU General Public License
      * along with this program; if not, write to the Free Software Foundation,
      * Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307   USA
      **************************************************************************
      *%%TS  SD  19961021  112309  MROWE       REL-V3R1M0  5763-PW1
      *%%EC
     A                                      DSPSIZ(24 80 *DS3                  -
     A                                             27 132 *DS4)
     A                                      CA03(03)
     A                                      ALTHELP
     A                                      HELP(01)
     A                                      MNUCNL(CA12 12)
     A          R DUMMY                     ASSUME
     A                                  1  2' '
     A          R MNUBARR
      *%%TS  SD  19940819  093451  MROWE       REL-V2R3M0  5738-PW1
     A                                      MNUBAR
     A                                      OVERLAY
     A                                      MNUBARDSP(&OPTION)
     A            SELEC          2Y 0B  1  2MNUBARSEP((*DSPATR RI) (*CHAR '.'))
     A                                      MNUBARCHC(1 PULL1 '>Database')
     A                                      MNUBARCHC(2 PULL2 '>Links')
     A                                      MNUBARCHC(3 PULL3 '>Scripts')
     A                                      MNUBARCHC(4 PULL4 '>Quit')
     A                                      MNUBARCHC(5 PULL5 '>Help')
     A            OPTION         2S 0H
      *
     A          R PULL1
      *%%TS  SD  19940819  093451  MROWE       REL-V2R3M0  5738-PW1
     A                                      PULLDOWN(*SLTIND)
     A                                      WDWBORDER((*COLOR WHT) (*DSPATR RI)-
     A                                       (*CHAR '...:::.:'))
     A            P1CHOI         2Y 0B  1  2SNGCHCFLD
     A                                      CHECK(ER)
     A                                      CHOICE(1 'Create >Library')
     A                                      CHOICE(2 'Create >Program file set')
      *
     A          R PULL2                     PULLDOWN
     A                                      WDWBORDER((*DSPATR RI) +
     A                                                (*COLOR WHT) +
     A                                                (*CHAR '...:::.:'))
     A            P2CHOI         2Y 0B  1  2SNGCHCFLD
     A                                      CHOICE(1 'Edit DBG >Links')
     A                                      CHECK(ER)
      *
     A          R PULL3                     PULLDOWN
     A                                      WDWBORDER((*DSPATR RI) +
     A                                                (*COLOR WHT) +
     A                                                (*CHAR '...:::.:'))
     A            P3CHOI         2Y 0B  1  2SNGCHCFLD
     A                                      CHOICE(1 '>Create DBG Script')
     A                                      CHOICE(2 '>Edit DBG Scripts')
     A                                      CHOICE(3 '>Validate DBG Script')
     A                                      CHOICE(4 'E>xecute DBG Script')
     A                                      CHECK(ER)
      *
     A          R PULL4                     PULLDOWN
     A                                      WDWBORDER((*DSPATR RI) +
     A                                                (*COLOR WHT) +
     A                                                (*CHAR '...:::.:'))
     A            P4CHOI         2Y 0B  1  2SNGCHCFLD
     A                                      CHOICE(1 '>Quit')
     A                                      CHCACCEL(1 'F3')
     A                                      CHECK(ER)
      *
     A          R PULL5                     PULLDOWN
     A                                      WDWBORDER((*DSPATR RI) +
     A                                                (*COLOR WHT) +
     A                                                (*CHAR '...:::.:'))
     A            P5CHOI         2Y 0B  1  2SNGCHCFLD
     A                                      CHOICE(1 '>Help')
     A                                      CHCACCEL(1 'F1')
     A                                      CHECK(ER)